Output для Access отчета

Пример вывода данных:

Enum opgRptType
   XLS = 1
   RTF = 2
   SNAPSHOT = 3
   HTML = 4
End Enum

где

• XLS = вывод в Excel
• RTF = вывод в Rich Text Format
• SNAPSHOT = вывод в Access snapshot формат
• HTML = вывод в HTML

Если lngRptType не описан, то отчет открывается в Print Preview режиме.

Function GetReport(Optional lngRptType As opgRptType) As Boolean
    
    Dim acApp As Access.Application
    Dim strReportName As String
    Dim strReportPath As String
        
   Const SAMPLE_DB_PATH As String = "c:\program files\" _
      & "microsoft office\office\samples\northwind.mdb"
    
   strReportName = "Название отчета"
   strReportPath = Options.DefaultFilePath(wdDocumentsPath) & "\"

   ' Старт приложения.
   Set acApp = GetObject(SAMPLE_DB_PATH, "Access.Application")
   With acApp
      ' Вывод в специальном формате.
      With .DoCmd
         Select Case lngRptType
            Case XLS
               .OutputTo acOutputReport, strReportName, _
                  acFormatXLS, strReportPath & "autoxls.xls", True
            Case RTF
               .OutputTo acOutputReport, strReportName, _
                  acFormatRTF, strReportPath & "autortf.rtf", True
               ' Этот формат SNAPSHOT (т.е. программа просмотра) должна быть установлена,
               '  т.к. по умолчанию ее может и не быть.
            Case SNAPSHOT
               .OutputTo acOutputReport, strReportName, _
                  acFormatSNP, strReportPath & "autosnap.snp", True
            Case HTML
               .OutputTo acOutputReport, strReportName, _
                  acFormatHTML, strReportPath & "autohtml.htm", _
                  True, "NWINDTEM.HTM"
            Case Else
               acApp.Visible = True
               .OpenReport strReportName, acViewPreview
         End Select
      End With
      ' Закрытие приложения
      If Not .UserControl Then
         acApp.Quit
         Set acApp = Nothing
      End If
   End With
   GetReport = True
End Function